Grammar

Grammar for Xoom Processor, written in EBNF notation and presented as a railroad diagram.

Click for more information on Extended Backus-Naur From (EBNF) notation, and railroad diagrams.

Command  ::= 'xp' Options Source ( Subsequence | Operation | XmlFormat )*
Options  ::= ( '--describe' | '-d' )? '--enable-set'? ( '-v' n )? ( '--comparer-config' ComparerFileName )?
           | ( '--help' | '-h' )?
Source   ::= ServerName? ':' Query?
           | XmlFile
           | XoomFolder '\'
Subsequence
         ::= '(' ( Subsequence | Operation | XmlFormat )+ ')'
Operation
         ::= Output
           | Deploy
           | CustomCommand
           | Transform
           | Combine
Output   ::= '@'
           | TargetFileName
           | TargetXoomFolder '\'
Deploy   ::= ServerName? ':'
CustomCommand
         ::= ServerName? ( '::SendSxp' | '::GetCustomQuery' )
Transform
         ::= ( '#' | '%' ) ( '=:' ParameterName '=' ParameterValue )* XsltFile
Combine  ::= ( '+' | '*+' | '+*' | '+!' | '-' ) Source
XmlFormat
         ::= '[:' XmlOptionList ':]'
XmlOptionList
         ::= XmlOption ( ',' XmlOptionList )*
XmlOption
         ::= C14N
           | Indent
           | OmitDecl
           | 'default'
C14N     ::= ( '+' | '-' )? 'c14n' 'rf'?
Indent   ::= 'indent=' [0-9]+ ( 's' | 't' )
OmitDecl ::= '-'? ( 'OmitXmlDeclaration' | 'omitdecl' )
MaxItemsInDir ::= 'MaxItemsInDir=' [0-9]+

Railroad diagram for grammar entity Command in Xoom Processor.